CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
PROJECT(MorphoGraphX CXX C)
SET(MGX_VERSION 1.0)
SET(MGX_REVISION 1280)

# Get build number from SVN
# We shouldn't need this, but Subversion_WC_INFO throws an error if anything goes wrong. 
SET(USE_SVN_BUILD_NUMBER FALSE CACHE BOOL "Get the build number automatically from the SVN. Set to false for exported copy.")
FIND_PACKAGE(Subversion)
IF(Subversion_FOUND AND USE_SVN_BUILD_NUMBER)
  Subversion_WC_INFO(${CMAKE_HOME_DIRECTORY} MGX)
  IF(MGX_WC_REVISION)
    SET(MGX_REVISION ${MGX_WC_REVISION})
  ENDIF()
ENDIF()
MESSAGE(STATUS "Configuring MorphoGraphX ${MGX_VERSION}.${MGX_REVISION}")

SET(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
SET(ENV{LC_ALL} C)
SET(CMAKE_MODULE_PATH ${MorphoGraphX_SOURCE_DIR}/CMakeScripts CACHE PATH "Path to cmake scripts" FORCE)

SET(QT_USE_QTXML TRUE)
SET(QT_USE_QTOPENGL TRUE)
SET(QT_USE_QTDESIGNER TRUE)
SET(QT_USE_QTUITOOLS TRUE)
FIND_PACKAGE(Qt4 REQUIRED)
FIND_PACKAGE(OpenGL REQUIRED)
FIND_PACKAGE(GLEW REQUIRED)
FIND_PACKAGE(CUDA REQUIRED)
FIND_PACKAGE(OpenMP REQUIRED)
FIND_PACKAGE(Thrust)
FIND_PACKAGE(TIFF REQUIRED)
FIND_PACKAGE(PythonLibs)
FIND_PACKAGE(PythonInterp)
FIND_PACKAGE(GSL REQUIRED)


SET(INSTALL_SCRIPTS TRUE CACHE BOOL "Launch the install scripts or not.")

SET(USE_OPENMP TRUE)

INCLUDE_DIRECTORIES(SYSTEM ${QT_INCLUDE_DIR})
INCLUDE(${QT_USE_FILE})

OPTION(WATCH_PROCESS_FOLDERS "Decide if the process folder is watched and the processes reloaded during MorphoGraphX
runtime." OFF)

IF(WIN32)
  SET(MODULE_TYPE SHARED)
ELSE()
  SET(MODULE_TYPE MODULE)
ENDIF()

# Allow for mixing system libs and full path libs
if(COMMAND cmake_policy)
  cmake_policy(SET CMP0003 NEW)
endif(COMMAND cmake_policy)

MACRO(ADD_OPTIONS var added_options)
  STRING(REPLACE " " ";" LST "${${var}}")
  FOREACH(OPT ${added_options})
    LIST(FIND LST ${OPT} pos)
    IF(pos EQUAL -1)
      LIST(APPEND LST ${OPT})
    ENDIF()
  ENDFOREACH()
  STRING(REPLACE ";" " " ${var} "${LST}" )
ENDMACRO(ADD_OPTIONS)

TRY_COMPILE(CIMG_COMPILES ${CMAKE_CURRENT_BINARY_DIR}/test_cimg ${CMAKE_CURRENT_SOURCE_DIR}/test_cimg.cpp OUTPUT_VARIABLE TEST_CIMG_RESULT)
IF(NOT CIMG_COMPILES)
  MESSAGE(SEND_ERROR "CImg not found or too old (required version: 1.4.6). Output:\n${TEST_CIMG_RESULT}")
ENDIF()

# libMGXViewer
SET (MGXVIEWER_SOURCE_DIR "${MorphoGraphX_SOURCE_DIR}/libMGXViewer")
SET (MGXVIEWER_LIBRARY_PATH "${CMAKE_CURRENT_BINARY_DIR}/libMGXViewer/MGXViewer/libMGXViewer.so")
ADD_SUBDIRECTORY("${MGXVIEWER_SOURCE_DIR}/MGXViewer")

SET(MGX_ADDONS "")
FIND_PACKAGE(AddOns)

MESSAGE(MGX Addons: ${MGX_ADDONS})

# CPack stuff
SET(CPACK_DEBIAN_PACKAGE_SHLIBDEPS TRUE CACHE BOOL "Auto-detect Debian Dependancies")
SET(CPACK_PACKAGE_CONTACT "Richard S. Smith <smith@mpipz.mpg.de>" CACHE STRING "Debian package contact")
SET(CPACK_BINARY_DEB TRUE CACHE BOOL "")
SET(CPACK_BINARY_STGZ FALSE CACHE BOOL "")
SET(CPACK_BINARY_TGZ FALSE CACHE BOOL "")
SET(CPACK_BINARY_TZ FALSE CACHE BOOL "")
SET(CPACK_SOURCE_TBZ2 FALSE CACHE BOOL "")
SET(CPACK_SOURCE_TGZ TRUE CACHE BOOL "")
SET(CPACK_SOURCE_TZ FALSE CACHE BOOL "")
SET(CPACK_SET_DESTDIR true)

SET(CPACK_PACKAGE_VERSION ${MGX_REVISION})
SET(CPACK_PACKAGE_VERSION ${MGX_VERSION}.${MGX_REVISION})

SET(CPACK_PACKAGE_NAME "MGX")
SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "MorphoGraphX: A tool for 4D image processing (and more!)")
SET(CPACK_DEBIAN_PACKAGE_CONTROL_EXTRA "${CMAKE_CURRENT_SOURCE_DIR}/prerm" "${CMAKE_CURRENT_SOURCE_DIR}/postinst" )
EXEC_PROGRAM(lsb_release ARGS -si OUTPUT_VARIABLE MGX_OS)
EXEC_PROGRAM(lsb_release ARGS -sr OUTPUT_VARIABLE MGX_OS_RELEASE)

# set package name
SET(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}${ARCH32}-${MGX_VERSION}.${MGX_REVISION}-${MGX_OS}${MGX_OS_RELEASE}${MGX_ADDONS}")

# Inflate Deflate SRC
ADD_SUBDIRECTORY("${MorphoGraphX_SOURCE_DIR}/src")

# find arch
IF("${CMAKE_SIZEOF_VOID_P}" EQUAL "4") 
  SET(ARCH32 "32")
ENDIF()

# Documentation
SET(DOC_PATH share/doc/MorphoGraphX)

# User manual
INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/doc/MGXUserManual.pdf DESTINATION ${DOC_PATH})

# Doxygen documentation
FIND_PACKAGE(Doxygen)
IF(DOXYGEN_FOUND)
  CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.cmake ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile)
  ADD_CUSTOM_TARGET(doc ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
  INSTALL(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc/html DESTINATION ${DOC_PATH})
ENDIF()

# ITK Plugin
ADD_SUBDIRECTORY("ITK")
ADD_SUBDIRECTORY("VTK")

# Add install scripts for Linux
IF(UNIX)
  FIND_PROGRAM(XDG_ICON_RESOURCE xdg-icon-resource DOC "XDG icon resource program")
  FIND_PROGRAM(XDG_DESKTOP_MENU xdg-desktop-menu DOC "XDG desktop menu program")
  FIND_PROGRAM(XDG_MIME xdg-mime DOC "XDG mime program")
  SET(DESKTOP_FILES
    morphographx-MorphoGraphX.desktop
    morphographx-MorphoGraphX.xml
    src/images/Icon64.png
    src/images/Icon22.png
    src/images/FileIcon.png
    src/images/MeshIcon.png
    src/images/StackIcon.png)
  INSTALL(FILES ${DESKTOP_FILES} DESTINATION share/MorphoGraphX)

  IF(INSTALL_SCRIPTS)
    INSTALL(
      CODE "SET(XDG_ICON_RESOURCE ${XDG_ICON_RESOURCE})"
      CODE "SET(XDG_DESKTOP_MENU ${XDG_DESKTOP_MENU})"
      CODE "SET(XDG_MIME ${XDG_MIME})"
      SCRIPT install_desktop.cmake)
  ENDIF(INSTALL_SCRIPTS)

  ADD_CUSTOM_TARGET(uninstall
    COMMAND ${XDG_ICON_RESOURCE} uninstall --mode system --size 64 morphographx-MorphoGraphX
    COMMAND ${XDG_ICON_RESOURCE} uninstall --mode system --size 22 morphographx-MorphoGraphX
    COMMAND ${XDG_DESKTOP_MENU} uninstall --mode system ${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.desktop
    COMMAND ${XDG_MIME} uninstall --mode system ${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.xml
    COMMAND ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxv
    COMMAND ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxs
    COMMAND ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxm
    )

  SET(POST_INSTALL
    "#!/bin/bash
    ${XDG_ICON_RESOURCE} install --mode system --size 64 \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/Icon64.png\" morphographx-MorphoGraphX
    ${XDG_ICON_RESOURCE} install --mode system --size 22 \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/Icon22.png\" morphographx-MorphoGraphX
    ${XDG_DESKTOP_MENU} install --mode system \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.desktop\"
    ${XDG_MIME} install --mode system \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.xml\"
    ${XDG_ICON_RESOURCE} install --mode system --context mimetypes --size 48 \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/FileIcon.png\" application-morphographx.mgxv
    ${XDG_ICON_RESOURCE} install --mode system --context mimetypes --size 48 \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/StackIcon.png\" application-morphographx.mgxs
    ${XDG_ICON_RESOURCE} install --mode system --context mimetypes --size 48 \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/MeshIcon.png\" application-morphographx.mgxm
    /sbin/ldconfig")

    SET(UNINSTALL
      "#!/bin/bash
      ${XDG_ICON_RESOURCE} uninstall --mode system --size 64 morphographx-MorphoGraphX
      ${XDG_ICON_RESOURCE} uninstall --mode system --size 22 morphographx-MorphoGraphX
      ${XDG_DESKTOP_MENU} uninstall --mode system \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.desktop\"
      ${XDG_MIME} uninstall --mode system \"${CMAKE_INSTALL_PREFIX}/share/MorphoGraphX/morphographx-MorphoGraphX.xml\"
      ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxv
      ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxs
      ${XDG_ICON_RESOURCE} uninstall --mode system --context mimetypes --size 48 application-morphographx.mgxm")

      FILE(WRITE ${CMAKE_BINARY_DIR}/post_install.sh "${POST_INSTALL}")
      FILE(WRITE ${CMAKE_BINARY_DIR}/uninstall.sh "${UNINSTALL}")

      INSTALL(PROGRAMS ${CMAKE_BINARY_DIR}/post_install.sh ${CMAKE_BINARY_DIR}/uninstall.sh DESTINATION share/MorphoGraphX)
ENDIF()
INCLUDE(CPack)
